Exo 9 : Feu tricolore complet

Exo 9 : Feu tricolore complet avec bouton piéton

C'est le projet de synthèse du chapitre ! Tu vas combiner tout ce que tu as appris : LEDs, digitalRead, toggle, debounce, et tu vas découvrir un nouveau concept puissant — la machine à états.

Simulation du feu tricolore

Observe le cycle du feu et demande le passage piéton :

La machine à états

Le feu tricolore est un exemple parfait de machine à états (state machine). L'idée : le système est toujours dans un état précis, et des conditions déclenchent les transitions.

Le feu reste VERT jusqu'à ce qu'un piéton appuie. Ensuite : JAUNE (3s) → ROUGE (5s) → PIÉTON (4s + buzzer) → retour au VERT.

Schéma du circuit

3 LEDs (rouge D4, jaune D5, verte D6) + bouton piéton D2. Le buzzer (D8) est ajouté dans le montage.

Montage pas à pas

LED rouge en colonne 4, jaune en 8, verte en 12. Chacune avec résistance 220Ω verticale traversant le fossé. Câbles vers D4 (rouge), D5 (jaune), D6 (vert). GND partagé.

Fonctions personnalisées

Au lieu de répéter du code, on crée des fonctions pour chaque action du feu :

void allumerVert() {
  digitalWrite(LED_R, LOW);
  digitalWrite(LED_J, LOW);
  digitalWrite(LED_V, HIGH);
}

void allumerJaune() {
  digitalWrite(LED_R, LOW);
  digitalWrite(LED_J, HIGH);
  digitalWrite(LED_V, LOW);
}

void allumerRouge() {
  digitalWrite(LED_R, HIGH);
  digitalWrite(LED_J, LOW);
  digitalWrite(LED_V, LOW);
}

Nouveau : switch / case

Tu connais déjà if / else pour tester une condition. Mais quand on a plusieurs valeurs possibles pour une même variable, on utilise switch — c'est plus lisible qu'une chaîne de if/else :

// Avec if/else (lourd) :
if (etat == 0) { ... }
else if (etat == 1) { ... }
else if (etat == 2) { ... }

// Avec switch (propre) :
switch (etat) {
  case 0:
    // Code pour état 0
    break;
  case 1:
    // Code pour état 1
    break;
  case 2:
    // Code pour état 2
    break;
}

Code : la machine à états

On utilise un enum (ici des constantes) pour nommer chaque état, et un switch dans loop() pour gérer les transitions :

const int VERT = 0;
const int JAUNE = 1;
const int ROUGE = 2;
const int PIETON = 3;

int etat = VERT;
unsigned long dernierChangement = 0;
bool demandeP = false;

void loop() {
  // Lire le bouton piéton
  if (digitalRead(BTN) == LOW && !demandeP) {
    demandeP = true;
  }

  unsigned long t = millis() - dernierChangement;

  switch (etat) {
    case VERT:
      allumerVert();
      if (demandeP) {
        etat = JAUNE;                // → transition !
        dernierChangement = millis();
      }
      break;

    case JAUNE:
      allumerJaune();
      if (t > 3000) {
        etat = ROUGE;
        dernierChangement = millis();
      }
      break;

    case ROUGE:
      allumerRouge();
      if (t > 5000) {
        etat = PIETON;
        dernierChangement = millis();
      }
      break;

    case PIETON:
      allumerRouge();
      tone(8, 1000, 100);  // Bip buzzer
      if (t > 4000) {
        demandeP = false;
        etat = VERT;
        dernierChangement = millis();
      }
      break;
  }
}

Exercice : complète les transitions

Remplis les trous pour compléter la machine à états. Quel est l'état suivant après chaque condition ?

Regarde le diagramme d'états ci-dessus : VERT → ??? → ROUGE → ???

Défis bonus